Carrefour numérique² - fablab animations:ateliers_openscad:exercices

Tuto OPENSCAD Couleur et transparence

2020-04-18T12:27:45+02:00

Tuto OPENSCAD Couleur et transparence

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Cette vidéo montre comment mettre des couleurs avec OpenSCAD et ajuster la transparence de pièces.

image par Ryan Zlomek

Vidéos

Vous n'aimez pas les vidéos ou les vidéos ne vous aiment pas, vous pouvez télécharger le script de la vidéo Texte en 3D. La vidéo ne comporte volontairement pas de paroles audio, tous les indications sont écrites en blanc sur fond noir.

Astuces et défis

Défi : faire une cible

Aides

Défi OpenSCAD Cube percé

2020-03-30T15:21:44+02:00

Défi OpenSCAD Cube percé

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-sa
Fichiers : defi_openscad_cube_carre_.stl, defi_openscad_cube_carre_.scad

Table des matières

Défi OpenSCAD Cube percé

Consigne : Reproduire la figure ci-dessous !

méthode A : 7 lignes & 5 fonctions différentes

Voir l'objet en 3D

Besoin d'aide, lisez la suite !

Vidéos

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (papier et crayon peuvent être utile )

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode A : Un cube percé par des cylindres centrés sur ses faces et par une sphère en son centre.

3. Les fonctions utiles

méthode A :

la différence : difference(){…}
le déplacement : translate([x,y,z]){…}
la rotation : rotate([x,y,z]){…}
le cylindre : cylinder(d1,d2,h);
la sphère : sphere (d);
le cube : cube();

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter :

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

méthode A :

Pensez bien à centrer les pièces center=true

Solutions

méthode A :

$fn=100;
difference(){
    cube(50,center=true);
    cylinder(r=10,h=120, center=true);
    rotate([90,0,0]){cylinder(r=10,h=120,center=true);}
    rotate([0,90,0]){cylinder(r=10,h=120,center=true);}
    sphere(r=20);
}

Défi OpenSCAD dé classique

2020-04-04T15:52:14+02:00

Défi OpenSCAD dé classique

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD dé classique
- Aides
- Solutions

Consigne : Réaliser un dé classique à 6 faces

Besoin d'aide, lisez la suite !

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (Papier et crayon peuvent être utiles). Décomposez l'objet final en plusieurs petits objets.

2. Phase explicative

Si vous ne savez pas par où commencer :

méthode dé 1: Le principal objet du dé est un cube (centré, c'est plus simple), dont les arrêtes sont arrondies. La somme des faces opposées du dé fait 7. Pour faire les trous des faces, il est possible de “soustraire” un cylindre par point: Faire une face avec les 7 points (Cf. schéma):

o_ x _o

o_ o _o

o_ x _o

Copier les “points” et les faire tourner en fonction de la face. Apliquer une différence au tout.

méthode dé 2: Il s'agit presque de la même chose, mais le corps du dé est l'ensemble des points communs à une sphère et un cube.

3. Les fonctions utiles

le cylindre : cylinder(d,h);
le cube :cube();
la sphere : sphere(d=); (pour le minkowski)

la différence : difference(){…}
le déplacement : translate([x,y,z]){…}
la rotation : rotate([x,y,z]){…}
minkowski : minkowski() methode 1
intersection : intersection() méthode 2

le nombre de faces des courbes : $fn=x;

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe
Déplacer les formes de la bonne distance.
Rester cohérant avec les fonctions de centrage (les utiliser tout le temps, ou jamais)

Solutions

atelier_de.scad

Suite à une réflexion, nous nous sommes rendus compte qu'il existait aussi une autre forme de dés. Le dé présenté est bien, mais roule moins que l'autre forme présenté.

atelier_de2.scad

Défi OpenSCAD Entonnoir

2020-04-03T17:58:24+02:00

Défi OpenSCAD Entonnoir

Fiche projet

Logiciels : Openscad
Réalisé par : plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Entonnoir
- Aides
- Solutions

Consigne : Réaliser un entonnoir en ligne de code !

méthode A : 9 lignes & 3 fonctions différentes
méthode B : 2 lignes & 2 fonctions différentes
méthode C : 7 lignes & 6 fonctions différentes

Voir l'objet en 3D

Besoin d'aide, lisez la suite !

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (papier et crayon peuvent être utile )

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode A : l'entonnoir est composé de deux cônes évidés superposés
méthode B : l'entonnoir est une forme géométrique qui subit une rotation extrudante
méthode C : l'entonnoir est composé d'une différence entre l'union d'un cône et d'une sphère, dans laquelle on l'évide par un cône, une sphère et un cube.

3. Les fonctions utiles

méthode A :

la différence : difference(){…}
le déplacement : translate([x,y,z]){…}
le cylindre/cône : cylinder(d1,d2,h);

méthode B :

la rotation extrudante : rotate_extrude(){…}
le polygone : polygon(…);

méthode A :

la différence : difference(){…}
le déplacement : translate([x,y,z]){…}
le cylindre/cône : cylinder(d1,d2,h);
la sphère : sphere (d);
le cube : cube©;

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

méthode A :

Se souvenir de comment on code un cône (ici, pointe vers le bas)
Positionner les pièces correctement les unes par rapport aux autres sans abuser du translate()
Faites attention, que les pièces qui sont extrudés dépasse bien des 2 côtés, afin d'éviter l'apparition de zébrures.
Une fois la pièce faite, si ce n'est pas déjà fait penser à la mise en variable

méthode B :

Se souvenir de comment on code un polynôme (ici, il faut 6 points)/ Le dessiner sur papier quadrillé peut aider
Partir d'un point , puis faire les positions extérieures de la forme, puis intérieur / Ne pas mettre deux fois le point de départ

Solutions

solution par étape : Fichier .SCAD code complet - Hélène

méthode A : Voir l'objet en 3D

a=80; // le diamètre extérieur supérieur du cône supérieur en mm
b=10; // le diamètre extérieur inférieur du cône supérieur en mm
c=8; // le diamètre extérieur inférieur du cône inférieur (dit le tube) en mm.
 
hc=60; // hauteur du cône supérieur en mm
ht=30;// hauteur du cône inférieur (dit le tube) en mm
 
e=3;// épaisseur en mm ( Attention pas moins de 3mm pour l'impression 3D)
$fn=60; // détail de la finition (en nombre de facettes) / Maillage
 
difference(){
    cylinder(d2=a, d1=b, h=hc);
    translate([0,0,-1]) cylinder(d2=a-e, d1=b-e, h=hc+2);
}
translate([0,0,-ht]){
    difference(){
        cylinder(d1=c, d2=b, h=ht);
        translate([0,0,-1]) cylinder(d1=c-e, d2=b-e, h=ht+2);  
    }
}

méthode B : Voir l'objet en 3D

a=80; // le diamètre extérieur supérieur du cône supérieur en mm
b=10; // le diamètre extérieur inférieur du cône supérieur en mm
c=8; // le diamètre extérieur inférieur du cône inférieur (dit le tube) en mm.
 
hc=60; // hauteur du cône supérieur en mm
ht=30;// hauteur du cône inférieur (dit le tube) en mm
 
e=3;// épaisseur en mm ( Attention pas moins de 3mm pour l'impression 3D)
$fn=60;
 
rotate_extrude($fn=80) polygon( points=[[c,0],[b,ht],[a,ht+hc],[a-e,ht+hc],[b-e,ht],[c-e,0]] );

méthode C : Voir l'objet en 3D

a=80; // le diamètre extérieur supérieur de la sphère supérieure en mm
b=10; // le diamètre extérieur inférieur du cône supérieur en mm
c=8; // le diamètre extérieur inférieur du cône inférieur (dit le tube) en mm.
 
hc=60; // hauteur du cône supérieur en mm
ht=30;// hauteur du cône inférieur (dit le tube) en mm
 
e=3;// épaisseur en mm ( Attention pas moins de 3mm pour l'impression 3D)
$fn=100; // détail de la finition (en nombre de facettes) / Maillage
 
difference(){
    union(){
        translate([0,0,a/2-e]) sphere(d=a);
        translate([0,0,-ht]) cylinder(d1=c, d2=b, h=ht);
        }
    translate([0,0,a/2-e-1]) sphere(d=a-e);
    translate([0,0,a-e]) cube(a,center=true);
    translate([0,0,-ht-1]) cylinder(d1=c-e, d2=b-e, h=ht+2);  
}

Défi OpenSCAD hélices ADN & Escalier

2020-08-19T15:32:35+02:00

Défi OpenSCAD hélices ADN & Escalier

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD hélices ADN & Escalier
- Aides
- Solutions

Consigne : Réaliser une hélice à ADN !

méthode A : 1 ligne & 1 fonction différente >Il s'agit du défi de l'atelier Programmer avec OpenSCAD.

Consigne : Réaliser un escalier!

méthode A : 5 ligne & 4 fonctions différentes >Il s'agit du défi de l'atelier Programmer avec OpenSCAD.

Besoin d'aide, lisez la suite !

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (papier et crayon peuvent être utile )

2. Phrase explicative

Si vous ne savez pas par où commencer :

hélice à ADN : ”…”

Escalier : ”…”

3. Les fonctions utiles

* le cube : cube(); * la rotation : rotate([x,y,z]){…} * le déplacement : translate([x,y,z]){…}

4. Pièges à éviter

D'abord, comprendre la logique, puis généraliser en utilisant une boucle for

3 éléments de l'hélice à ADN

cube([10,50,5],center=true);
translate([0,0,5*1]) rotate([0,0,15*1]) cube([10,50,5],center=true);
translate([0,0,5*2]) rotate([0,0,15*2]) cube([10,50,5],center=true);

3 éléments d'un escalier

cube([10,50,2],center=false);
translate([0,0,2*1]) rotate([0,0,5*1]) cube([10,50,2],center=false);
translate([0,0,2*2]) rotate([0,0,5*2]) cube([10,50,2],center=false);

Solutions

Une hélice à ADN

m=30;//nombre de marches
for(i=[1:m]){
translate([0,0,5*i]) rotate([0,0,15*i]) cube([10,50,5],center=true);
}

Un escalier de 100 marches

m=100;//nombre de marches
for(i=[1:m]){
  translate([0,0,2*i]) {
    rotate([0,0,10*i]) {
      cube([10,50,2],center=false);
  }}}

Défi OpenSCAD Défi Porte-bouteille & bouteilles

2020-04-01T16:30:52+02:00

Défi OpenSCAD Défi Porte-bouteille & bouteilles

Fiche projet

Logiciels : Openscad
Réalisé par : plogingenu, (bully)
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Défi Porte-bouteille & bouteilles

Consigne : Réaliser un porte bouteille et ses bouteilles !

méthode : A la Hélène

Voir l'objet en 3D (ln)

Besoin d'aide, lisez la suite !

Inspiration

L'article qui explique comment faire manuellement un porte bouteille original de manière traditionnel (perceuses, scies), nous a bien plu. Cependant, on préfère :

le faire à la manière FabLab en utilisant les outils (Découpeuse laser) - option A
en modulant les dimensions des bouteilles pour convenir à tou-te-s (limonades, bières, vins, eaux gazeuses …) - option B
en modulant le nombre de bouteilles voulu, (de 1 à plus infini) - option C
En faisant des trous au niveau de la base, pour être sur que les bouteilles ne bougent pas. - option D
en calculant automatique la longueur de corde nécessaire - option E
en modulant selon l'épaisseur de la planche utilisé - option F

Pour cela rien de mieux, qu'OpenSCAD, pour nous faire un générateur paramétrique de plan (.svg) de porte bouteille.

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (Papier et crayon peuvent être utiles.)

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode : à la Hélène
Une différence entre l'union de trois parallélépipèdes (arrondies) à des hauteurs différentes (socle,socle troué et haut troué) et, les formes de bouteilles plus une marge et des petits trous et leur symétrie.

3. Les fonctions utiles

méthode : ln

1. Créer une bouteille

Méthode simple

le cylindre : cylinder(d1,d2,h);

Méthode un peu plus compliquée

le cylindre : cylinder(d1,d2,h);
: hull(){…}
le déplacement : translate([x,y,z]){…}

Méthode pour les gens précis

polygone : polygon();
rotate_extrude : rotate_extrude();

2. Créer un pack de bouteilles paramétriques

Boucle for : for(){…}
Module :

3. Créer les planches

Méthode pour planches carrées

le cube :cube();
le déplacement : translate([x,y,z]){…}

Méthode pour planches au bord arrondi

le cube :cube();
le “Minkoski” : minkoski([x,y,z]){…}
le cylindre : cylinder(d1,d2,h);

4. Créer les petits trous

Méthode répétitive

le cylindre : cylinder(d1,d2,h);
le déplacement : translate([x,y,z]){…}

Méthode courte

le cylindre : cylinder(d1,d2,h);
le déplacement : translate([x,y,z]){…}
le miroir : mirror ([x,y,z]){…}

5. Assembler les différentes parties

la différence : difference(){…}

6. Réalisation de la poignée

le cylindre : cylinder(d1,d2,h);
le déplacement : translate([x,y,z]){…}
la rotation : rotate([x,y,z]){…}

7.Export en .svg

8.Modélisation de la corde (bonus)

9.Animation du modèle 3D (bonus)

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

Conseils : Projets complexes Plus le projet est complexes, plus il est important de travailler avec méthodologie

Prendre les vraies mesures d'une bouteille, plus réaliste
N'hésitez pas à utiliser la transparence ( # ) pour bien comprendre ou sont situées vos pièces
Lorsque que vous ne comprenez plus, ne mettez pas des valeurs au pif, faites une pause plutôt.
Enregistrer plusieurs versions de votre fichier, afin de retrouver rapidement une sauvegarde qui marche.
Commencez toujours par comprendre la logique, avant de généraliser (boucle for)
Bien vérifier qu'en changeant chaque variable, le modèle reste valable. Cela permet de vérifier si il n'y a pas d'erreur dans le code.
Commentez votre code, pour vous aider, mais aussi pour faciliter la documentation

Solutions par étapes

Créer une bouteille - Méthode simple

Voir l'objet en 3D

hb=230 ; // hauteur de la bouteille
hg=84; // hauteur du goulot
db=70; //diamètre ou largeur basse de la bouteille
dh=40; // diamètre ou largeur haute de la bouteille
 
cylinder(d=db, h=hb-hg, $fn=100); // gros cylindre
cylinder(d=dh, h=hb, $fn=100); //petit cylindre

Créer une bouteille - un peu plus compliquée

Voir l'objet en 3D

hb=230 ; // hauteur de la bouteille
hg=84; // hauteur du goulot
db=70; //diamètre ou largeur basse de la bouteille
dh=40; // diamètre ou largeur haute de la bouteille
hi=123; // hauteur intermédiaire
 
cylinder(d=db, h=hi);// gros cylindre
hull(){
translate([0,0,hi]){cylinder(d=db, h=1);}
translate([0,0,hb-hg]){cylinder(d=dh, h=1);}
}
translate([0,0,0]){cylinder(d=dh, h=hb);} //petit cylindre

Créer une bouteille - Méthode pour les gens précis

Voir l'objet en 3D

hb=230; //hauteur de la bouteille
hg=84; // hauteur du goulot
db=70; //diamètre ou largeur basse de la bouteille
dh=40; // diamètre ou largeur haute de la bouteille
hi=123;
rotate_extrude($fn=80){polygon( points=[[0,0],[db/2,0],[db/2,hi],[dh/2,hb-hg],[dh/2,hb],[0,hb]]);}

Créer un module bouteille();

module bouteille(hb=230,hi=123,hg=84,db=70,dh=40){
//hb, hauteur de la bouteille
//hg, hauteur du goulot
//db, diamètre ou largeur basse de la bouteille
//dh, diamètre ou largeur haute de la bouteille
//hi, hauteur intermédiaire
 
cylinder(d=db, h=hi);// gros cylindre
hull(){
translate([0,0,hi]){cylinder(d=db, h=1);}
translate([0,0,hb-hg]){cylinder(d=dh, h=1);}
}
translate([0,0,0]){cylinder(d=dh, h=hb);}
 
}
 
// bouteille();

Créer un pack de bouteilles paramétriques

Télécharger le code

Module bouteille +

db=70; // Rayon des trous, rt va de 0 à + infini,
esp= db+25; // espacemenent entre  les trous
Nx= 2; // Nx va de 0 à + infini, entier uniquement Compte +1
Ny= 1; //Ny=Nx, pour faire un damier carré, ou Ny = valeur au choix
 
for (j = [-Ny/2:Ny/2]){
  for (i = [-Nx/2:Nx/2]){
    translate ([i*esp,j*esp,0]) {bouteille();}
  }
}

Solutions finales

méthode : N'hésitez pas à faire varier les paramètres

Télécharger le code -

Votre méthode : N'hésitez pas à mettre vos codes ci-dessous :

Défi OpenSCAD Pyramide

2020-03-31T11:05:38+02:00

Défi OpenSCAD Pyramide

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Pyramide

Consigne : Réaliser une pyramide à base carrée !

méthode A : 1 ligne & 1 fonction différente >Il s'agit du défi de fin de l'atelier d'initiation OpenSCAD.
méthode B : 15 lignes & 3 fonctions différentes
méthode C : 3 lignes & 3 fonctions différentes
méthode D : 3 lignes & 3 fonctions différentes
méthode E : 1 lignes & 1 fonction différente

Voir l'objet en 3D

Besoin d'aide, lisez la suite !

Vidéo

Ne présente pas la méthode E.

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (papier et crayon peuvent être utile )

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode A : Astuce OpenSCAD : Contraindre le nombre de facettes à 4 d'un cône
méthode B : Extruder les 4 faces d'un cube
méthode C : Relier en continu, un grand cube de base à un minuscule cube de sommet
méthode D : Cumuler des parallélépipède de plus en plus petit
méthode E : Faites votre pyramide en mode polyèdre

3. Les fonctions utiles

méthode A :

le cylindre/cône : cylinder(d1,d2,h);
le paramètre du nombre de facettes : $fn

méthode B :

la différence : difference(){…}
le cube : cube();
la rotation : rotate([x,y,z]){…}

méthode C :

la fonction “Coque” : hull(){…}
le cube : cube();
le déplacement : translate([x,y,z]){…}

méthode D :

la boucle for : for(){…}
le cube : cube();
le déplacement : translate([x,y,z]){…}

méthode E :

le polyèdre : polyhedron();

Si vous ne connaissez pas bien l'utilisation d'une de ces fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

méthode A :

Connaitre l'astuce $fn=, qui contraint le nombre de faces d'un objet.

méthode B :

Créer un cube
Extrudé avec un autre parallélépipède sur un face
Puis généraliser le principe aux 3 autres faces

méthode C :

Créer un parallélépipède centrée, de faible hauteur (0.1mm ou moins) et d'une largeur de 20mm
Créer un parallélépipède centrée, de faible hauteur (0,1mm ou moins) et d'un faible largeur 0.1mm
Déplacer le petit parallélépipède jusqu'au sommet de la pyramide
Englober le code précédemment écrit dans un hull().

méthode D :

Créer un parallélépipède centrée, de faible hauteur (1 mm) et d'une largeur de 20mm
Créer un second, de la même hauteur (ou hauteur cumulée au choix) légèrement plus moins larges, qui est au dessus du premier (ou qui dépasse du premier)
Une fois la logique de passage, entre les différents cube comprises, généraliser la logique en utilisant une boucle for()

méthode E :

Partir sur une pyramide dont la base est centrée sur le plan XY
Déterminer les coordonnées des 5 points qui seront utilisés : les 4 points de la base (dont le z=0) et le sommet de la pyramide (dont le x=0 et le y=0)
Entrer les coordonnées de ces points dans l'ordre, points=[ [sommet], [point1],[point2] ,[point3] , [point4] ]
Entrer les combinaisons qui composent les différentes faces. Attention, OpenSCAD ne commence pas à compter à un 1 mais à 0. Le sommet est un ainsi égale à 0, le point 1 au 1, le point 2 au 2, le point 3 au 3 et le point 4 au 4. La première face est la base de la pyramide avec les 4 points, puis suivent les 4 faces de la pyramide chacune composé de 3 points, dont le sommet.

Solutions

Une pyramide de 20 mm de côté et de hauteur

méthode A :

c=20;// côté de la pyramide, ici 20 mm
cylinder(r1=c,r2=0,h=c/2,$fn=4);

méthode B :

c=20;// côté de la pyramide, ici 20 mm
 
difference(){
    translate([0,0,c/5]){
            cube([c,c,c/2],center=true);
    }
    rotate([-45,0,0]){
        translate([0,0,c/2]){
            cube([c,c,c/2],center=true);
        }
    }
    rotate([45,0,0]){
        translate([0,0,c/2]){
            cube([c,c,c/2],center=true);
        }
    }
     rotate([0,45,0]){
        translate([0,0,c/2]){
            cube([c,c,c/2],center=true);
        }
    }
     rotate([0,-45,0]){
        translate([0,0,c/2]){
            cube([c,c,c/2],center=true);
        }
    }
}

méthode C :

c=20;// côté de la pyramide, ici 20 mm
hull(){
    cube([c,c,0.01], center=true);
    translate([0,0,c]){cube([0.01,0.01,1],center=true);}
 }

méthode D :

c=20;// côté de la pyramide, ici 20 mm
for(i=[0:c]){
    translate([0,0,i]){
        cube([c-i,c-i,1],center=true);
    }
}

méthode E :

c=20; //le côté de la pyramide, ici, 20mm
polyhedron (
 points=[[0,0,c/2], [-c/2,-c/2,0], [-c/2,c/2,0],[c/2,c/2,0], [c/2,-c/2,0] ],
 faces=[[1,2,3,4],[0,1,2],[0,2,3],[0,3,4],[0,1,4] ]
);

Défi OpenSCAD Verre à pied

2020-08-08T16:48:17+02:00

Défi OpenSCAD Verre à pied

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Verre à pied
- Aides
- Solutions

Consigne : Réaliser un verre à pied !

méthode : très nombreuses, à vous de nous partager la votre
méthode : Super rapide (4 lignes et 2 fonctions)
méthode : verre à pied classique (7 lignes et 5 fonctions)

Imaginez la forme que vous désirez ! Voir l'objet en 3D (verre super rapide) Voir l'objet en 3D (verre classique)

Besoin d'aide, lisez la suite !

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (Papier et crayon peuvent être utiles.)

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode : Le verre à pied est le plus souvent composé de trois parties :
- la base qui doit assurer la stabilité du verre,
- le pied qui sert à surélevé le verre et éviter de réchauffer le contenant avec la chaleur de nos mains,
- et le ballon contenant le liquide

méthode : Super rapide
- la base est un cône tronqué à 3/4/5/6/100 côtés
- le pied et le ballon sont une seule pièce, un cône inversé extrudé par un cône inversé plus grand.

méthode : verre à pied classique
- la base est un cône tronqué à 3/4/5/6/100 côtés
- le *pied* est un cylindre ( hauteur grande, rayon faible)
- le *ballon* est une sphère extrudée par une sphère légèrement plus petite (et plus haute) ET par un cube.

3. Les fonctions utiles

méthode : super rapide

la différence : difference(){…}
le cylindre/cône : cylinder(d1,d2,h);

méthode : verre à pied classique

la différence : difference(){…}
le cylindre/cône : cylinder(d1,d2,h);
le déplacement : translate([x,y,z]){…}
le cube :cube();
la sphere : sphere(d=);

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

méthode : Super rapide

Pas de difficultés particulières, on superpose 3 formes donc la base est centrée sur le point d'origine.

méthode :Verre à pied classique

Déplacer les formes de la bonne distance :
Poser la base et le pied, centrée sur le point d'origine (donc pas de translate(), la superposition du pied et de la basse n'est pas gênante.)
Déplacer la sphère extérieure de la longueur du pied
Déplacer la sphère intérieur de la longueur du pied plus un léger écart (qu'on peut calculer comme le rayon de la sphère extérieure moins le rayon de la sphère intérieure)
Déplacer le cube de la longueur du pied plus le rayon de la sphère extérieure.
Il est possible d'utiliser un translate() pour chaque pièce, mais le code sera plus lourd, il est aussi possible de faire un translate de translate(), cf .code ci-dessous

Solutions

méthode : super rapide (4 lignes et 2 fonctions)

Changer le $fn= pour faire varier le nombre de facettes de chaque solide

Voir l'objet en 3D

difference(){
cylinder(r1=0, r2= 40, h =100, $fn=100); //cône extérieur
cylinder(r1=0, r2= 38, h =100+1, $fn=100); //cône intérieur
}
cylinder(r1=40, r2=5, h= 10, $fn=5); // la base

méthode : Verre à pied classique (7 lignes et 5 fonctions)

N'hésitez pas à faire varier les paramètres lv et hv

Voir l'objet en 3D

lv=40 ; //largeur du verre, ici 40mm
hv=100; // hauteur du verre, ici 100mm
 
translate([0,0,hv]){
    difference(){
        sphere(r=lv,$fn=100); //sphere extérieur
        translate([0,0,lv]){cube(2*lv, center= true);}//cube
        sphere(r=lv-2, $fn=100); //sphère intérieur  
       }
}
cylinder(r=lv/10,h=hv-lv,$fn=100); // le pied
cylinder(r1=lv,r2=lv/10,h=hv/10,$fn=100); // la base

Votre méthode : N'hésitez pas à mettre vos codes ci-dessous :

....

....

Depuis les premiers ateliers OpenSCAD en 2016, vous avez été nombreuses et nombreux à réaliser le défi du verre à pied, toujours à votre manière et avec votre créativité :

Titre du défi

2020-04-03T11:47:54+02:00

Titre du défi

Défi OpenSCAD (...)

Fiche projet

Logiciels : Openscad
Réalisé par : auteur
Licence : cc-by-nc

Solutions

Votre photo jpg ou png Consigne : …..

méthode :

Voir l'objet en 3D Votre fichier .st

Besoin d'aide, lisez la suite !

Vidéos

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (Papier et crayon peuvent être utiles.)

2. Phrase explicative

Si vous ne savez pas par où commencer :

méthode : …
- ….

3. Les fonctions utiles

Si vous ne connaissez pas bien l'utilisation d'une de ses fonctions, il peut être utile d'aller voir les exercices du wiki ou la page Aide-Mémoire OpenSCAD.

4. Pièges à éviter

En général :

Le point-virgule
Bien ouvrir et fermer les parenthèses, crochets et accolades
Les erreurs de frappe

méthode :

Solutions

méthode :

Changer le $fn= pour faire varier le nombre de facettes de chaque solide

Voir l'objet en 3D

...

Votre méthode : N'hésitez pas à mettre vos codes ci-dessous :

....

Défi OpenSCAD Ressort

2020-08-19T17:01:11+02:00

Défi OpenSCAD Ressort

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Ressort
- Aides
- Solutions

Consigne : Réaliser un ressort ! >Il s'agit du défi de fin de l'atelier Programmer avec OpenSCAD.

méthode A :
méthode B :

Aides

1. Réfléchissez

Prenez vraiment le temps de réfléchir (Papier et crayon peuvent être utiles). Décomposez l'objet final en plusieurs petits objets.

2. Phase explicative

Si vous ne savez pas par où commencer :

3. Les fonctions utiles

4. Pièges à éviter

Solutions

méthode A (Méthode Bully)

nb_sphere=100;
nbboucle=0.5;//nb_sphere/360
diamsphere=20;
$fn=20;
  for ( i= [0:nb_sphere] )
      rotate([0,0,i*(nbboucle*360/nb_sphere)]) {
          translate([0,2.5*diamsphere,i]){
              sphere(d=diamsphere);
          }
        translate([0,-2.5*diamsphere,i]){
              sphere(d=diamsphere);
          }
        translate([2.5*diamsphere,0,i]){
            sphere(d=diamsphere);
          }
        translate([-2.5*diamsphere,0,i]){
            sphere(d=diamsphere);
            }         
          }
 
difference(){
  $fn=60;
  union(){
    translate([0,0,-0.25*diamsphere]){
      cylinder(r=3*diamsphere, h=10,center=true);
    }
    translate([0,0,5+nb_sphere]){
      cylinder(r=3*diamsphere, h=10, center=true);
    }
  }
  translate([0,0,-diamsphere]){
    cylinder(r=2*diamsphere,h=1.5*nb_sphere);
  }
  }

méthode B (Méthode Hélène)

p=50; //rayon par rapport au centre
ds=10; // diamètre de la sphère
pas=2; // pas
iteration =200; // gère aussi la hauteur de la pièce
 
// Le coeur du ressort
for(positionX=[p,-p], positionY=[p,-p],i=[1:iteration]){ 
rotate([0,0,i*pas])
 translate([positionX,positionY,i*pas])
    sphere(ds, $fn=75);
}
//base et haut du ressort
difference(){ 
 union(){
    translate([0,0,-ds]){cylinder(r=2*(p-ds)+2,h=ds,$fn=100);}
    translate([0,0,iteration*pas]){cylinder(r=2*(p-ds)+2,h=ds,$fn=100);}
 }
 translate([0,0,-ds-0.1]){cylinder(r=p+ds,h=iteration*pas+2*ds+0.2,$fn=100);}
}

Tuto OPENSCAD Texte en 3D

2020-04-08T11:13:59+02:00

Tuto OPENSCAD Texte en 3D

Fiche projet

Logiciels : Openscad
Réalisé par : bully, plogingenu
Licence : cc-by-nc

Table des matières

Défi OpenSCAD Ressort
- Aides
- Solutions

Votre photo jpg ou png Consigne : …..

méthode :

Cette vidéo montre comment utiliser OpenSCAD pour faire du texte.

Vidéos

Astuces et défis

Comment revenir à la ligne ?

La commande de texte d'OpenSCAD (2019) ne prend en charge aucune sorte de formatage multi-lignes. Il faudra ruser ! Une solution simple est d'écrire son texte définitif sous Inkscape, et de l'importer sous OpenSCAD.

Comment mettre le texte dans une variable ?

On notera de bien les guillemets au niveau de la mise en variable, et de mettre dans la fonction text(); , uniquement la variable sans guillemet.

A="Ceci est mon texte"; 
text(A);

porteclef.scad

Comment mettre des vrais smiley ou des caractères “autres” ?

Utiliser la fonction chr()

text(chr(9786)); 
text(chr(9788));

Comment “moduler” du texte ?

Utiliser la fonction str()

AGE= 18;
text(str("Joyeux ",AGE," ans !"));

Comment savoir le nombre de caractères contenu dans le texte ?

Utiliser la fonction len();

PRENOM ="Mon prénom"; // Tapez votre texte
l=len(PRENOM);
Echo(l);