Consigne : Réaliser un entonnoir en ligne de code !

• méthode A : X lignes & X fonctions
• méthode B : 2 lignes & 2 fonctions différentes

Voir l'objet en 3D

Réfléchissez !

Si vous ne savez pas par où commencer :

méthode 1 : l'entonnoir est composé de deux cônes évidés superposés

Pièges à éviter :

1. Se souvenir de comment on code un cône (ici, pointe vers le bas)
2. Positionner les pièces correctement les unes par rapport aux autres sans abuser du translate()
3. Faites attention, que les pièces qui sont extrudés dépasse bien des 2 côtés, afin d'éviter l'apparition de zébrures.
4. Une fois la pièce faite, si ce n'est pas déjà fait penser à la mise en variable

solution par étape : Fichier .SCAD code complet - Hélène

a=80; // le diamètre extérieur supérieur du cône supérieur en mm
b=10; // le diamètre extérieur inférieur du cône supérieur en mm
c=8; // le diamètre extérieur inférieur du cône inférieur (dit le tube) en mm.
 
hc=60; // hauteur du cône supérieur en mm
ht=30;// hauteur du cône inférieur (dit le tube) en mm
 
e=3;// épaisseur en mm ( Attention pas moins de 3mm pour l'impression 3D)
$fn=60; // détail de la finition (en nombre de facettes) / Maillage
 
difference(){
    cylinder(d2=a, d1=b, h=hc);
    translate([0,0,-1]) cylinder(d2=a-e, d1=b-e, h=hc+2);
}
translate([0,0,-ht]){
    difference(){
        cylinder(d1=c, d2=b, h=ht);
        translate([0,0,-1]) cylinder(d1=c-e, d2=b-e, h=ht+2);  
    }
}

méthode 2 : l'entonnoir est une forme géométrique qui subit une rotation extrudante

a=80; // le diamètre extérieur supérieur du cône supérieur en mm
b=10; // le diamètre extérieur inférieur du cône supérieur en mm
c=8; // le diamètre extérieur inférieur du cône inférieur (dit le tube) en mm.
 
hc=60; // hauteur du cône supérieur en mm
ht=30;// hauteur du cône inférieur (dit le tube) en mm
 
e=3;// épaisseur en mm ( Attention pas moins de 3mm pour l'impression 3D)
$fn=60;
 
rotate_extrude($fn=80) polygon( points=[[c,0],[b,ht],[a,ht+hc],[a-e,ht+hc],[b-e,ht],[c-e,0]] );